[Help] Custom main.scm save point loading problem

[GTA Loyalty]

Hi everyone. Ok, so, I've been working on a new main.scm for a few months. In this main I have putted the save point into a house and everything were ok until I code the fourth mission. Since that, everytime I try to load a savegame, the game it freezes into a black screen.

This is the thread of the savegame:
 

:SAVETHREADB_133271
thread 'SAVETHREADB' 
wait 0 
if 
  $ONMISSION == 0 
jf @SAVETHREADB_133271 
jump @SAVETHREADB_133326 

:SAVETHREADB_133326
wait 0 
if
  $ONMISSION == 0  
jf @SAVETHREADB_133271 
$SAVE2 = Pickup.Create(#PICKUPSAVE, 3, 2186.291, -1212.681, 1049.023)
jump @SAVETHREADB_133430 

:SAVETHREADB_133430
wait 0 
if 
   Pickup.Picked_up($SAVE2)
jf @SAVETHREADB_133488 
Player.CanMove($PLAYER_CHAR) = False
$ONMISSION = 1  
jump @SAVETHREADB_133578 

:SAVETHREADB_133488
wait 0 
if 
  $ONMISSION == 1 
jf @SAVETHREADB_133430 
Pickup.Destroy($SAVE2)
jump @SAVETHREADB_133271  

:SAVETHREADB_133578
wait 0 
03D8: show_save_screen 
jump @SAVETHREADB_133592 

:SAVETHREADB_133592
wait 0 
if 
83D9:   not save_done 
jf @SAVETHREADB_133616 
jump @SAVETHREADB_133592 

:SAVETHREADB_133616
fade 0 1000 
wait 0 
if 
   Player.Defined($PLAYER_CHAR)
jf @SAVETHREADB_133616 
fade 1 1000
023C: load_special_actor 'ZERO' as 1 // models 290-299 
016C: restart_if_wasted_at 2027.77 -1420.52 15.99 angle 137.0 town_number 0
Camera.Restore_WithJumpCut
Camera.SetBehindPlayer 
Actor.PutAt($PLAYER_ACTOR, 2188.044, -1212.571, 1049.023)
Actor.Angle($PLAYER_ACTOR) = -90.0
Player.CanMove($PLAYER_CHAR) = True
$ONMISSION = 0
wait 0
0296: unload_special_actor 1

:SAVE_4029
wait 0 
if 
023D:   special_actor 1 loaded 
else_jump @SAVE_4029 
09C7: change_player $PLAYER_CHAR model_to #SPECIAL01 
07FE: set_actor $PLAYER_ACTOR fighting_style_to 7 moves 6 
$ONMISSION = 0 
jump @SAVETHREADB_133271 

:SAVETHREADB_133748
wait 2500 
jump @SAVETHREADB_133748

I tried removing the special actor, the fighting style switch and that for testing and It didn't work either, so what could be? I really don't know what else to do.

Thank you.

[ZAZ]

can you realize the paradoxon of these codes of your script?

0296: unload_special_actor 1

:SAVE_4029
wait 0 
if 
023D:   special_actor 1 loaded 
else_jump @SAVE_4029

 

[GTA Loyalty]

Oh god. My bad, I didn't realize I putted the unload on the wrong line. But that's not the problem, the game still getting freeze

[ZAZ]

try this

:SAVETH_01
thread 'SAVETHB'

:SAVETH_03 
wait 0 
if 
  $ONMISSION == 0 
jf @SAVETH_03 
$SAVE2 = Pickup.Create(#PICKUPSAVE, 3, 2186.291, -1212.681, 1049.023) 

:SAVETH_14
wait 0 
if 
   Pickup.Picked_up($SAVE2)
jf @SAVETH_17 
Player.CanMove($PLAYER_CHAR) = False
$ONMISSION = 1  
jump @SAVETH_21 

:SAVETH_17
if 
  $ONMISSION == 1 
jf @SAVETH_14 
Pickup.Destroy($SAVE2)
jump @SAVETH_03  

:SAVETH_21
wait 350 
03D8: show_save_screen  

:SAVETH_25
wait 0 
if 
83D9:   not save_done 
jf @SAVETH_26 
jump @SAVETH_25 

:SAVETH_26
Actor.PutAt($PLAYER_ACTOR, 2188.044, -1212.571, 1049.023)
Actor.Angle($PLAYER_ACTOR) = -90.0
Player.CanMove($PLAYER_CHAR) = True
$ONMISSION = 0 
fade 0 0 

:SAVETH_28
wait 0 
if 
   Player.Defined($PLAYER_CHAR)
jf @SAVETH_28 
fade 1 1000
023C: load_special_actor 'ZERO' as 1 // models 290-299 
016C: restart_if_wasted_at 2027.77 -1420.52 15.99 angle 137.0 town_number 0
Camera.Restore_WithJumpCut
Camera.SetBehindPlayer 

:SAVETH_32
wait 0 
if 
023D:   special_actor 1 loaded 
else_jump @SAVETH_32 
09C7: change_player $PLAYER_CHAR model_to #SPECIAL01 
07FE: set_actor $PLAYER_ACTOR fighting_style_to 7 moves 6
0296: unload_special_actor 1
jump @SAVETH_03

 

[GTA Loyalty]

Well, looks like it worked! Thank you so much, Zaz!