Change color IDs available at transfender

[j7n]

Is it possible to change the color IDs in Transfender to include colors over 128? I know that the colors themselves associated with low ids can be changed in carcols.dat. Instead I want the available color numbers changed. I searched the forum and found where the carcols are located in memory (all carcols are there) and a reference to "carmod1" script, which somehow generates the subset list, which I am not able understand, as nothing in that file looks like a list or contains the numbers given in sequence.

 

https://gtaforums.com/topic/194199-documenting-gta-sa-memory-addresses/?page=43&tab=comments#comment-1061749308

 

 

 

 

 I want to try to set special SAMP colors in multiplayer on a server that doesn't provide a good interface for painting, but allows to use transfender.
 

[ZAZ]

this is the only code to show the color panel

0964: create_square_color_panel 'CARM1' position 400.0  20.0  width 25.7 columns 8 interactive 1 background 1 alignment 1 panelID L_PANEL_VAR

the construction of the panel is hardcoded

also increasing columns from columns 8 to columns 10 have no effect

below a testscript

Spoiler

get in a car then press "YES" key to show color panel

use up, down, left, right to move to color squares and change color

press enter to quit

{$CLEO .cs}
:Menue_COLOR_HighLevel
03A4: name_thread 'MENUCOL'

const  
L_PANEL_VAR = 0@
L_ACTIVE_ROW_VAR = 1@
L_PANEL_IS_SHOWN_VAR = 2@
end

while true
wait 0
    if
        0256:   player $PLAYER_CHAR defined
    then
            if
                L_PANEL_IS_SHOWN_VAR  == 0
            then    
                    if  and
                        00E1:   key_pressed  0  11//--- key = YES
                        00DF:   actor $PLAYER_ACTOR driving 
                    then                        
                        gosub @MENU_1
                    end
            else// if menue is shown, if L_PANEL_IS_SHOWN_VAR  == 1
                    if  or
                        00E1:   key_pressed  0  0//--- key = left/right
                        00E1:   key_pressed  0  1//--- key = forward/backward
                    then
                        gosub @Selection_1
                    end
                    if
                        00E1:   key_pressed  0  15//--- key = Enter/Exit
                    then                                                
                        gosub @Remove_panel
                    end
            end
    else//if player dies or gets arrested
            if
                L_PANEL_IS_SHOWN_VAR  == 1
            then
                gosub @Remove_panel//if player dies or gets arrested while meue is shown
            end    
    end
end

:MENU_1
03C0: 13@ = actor $PLAYER_ACTOR car
01B4: set_player $PLAYER_CHAR frozen_state  0 (frozen)
0826: toggle_hud  0
0964: create_square_color_panel 'CARM1' position 400.0  20.0  width 25.7 columns 8 interactive 1 background 1 alignment 1 panelID L_PANEL_VAR  // Colors
L_PANEL_IS_SHOWN_VAR = 1
return

:Remove_panel
08DA: remove_panel L_PANEL_VAR
L_PANEL_IS_SHOWN_VAR = 0
0826: toggle_hud  1
wait 500
01B4: set_player $PLAYER_CHAR frozen_state  1 (unfrozen)   
return


:Selection_1
08D7: L_ACTIVE_ROW_VAR = panel L_PANEL_VAR active_row
0A22: set_car_color_to_panel_color_panelID L_PANEL_VAR car 13@ colorslot 1 active_row L_ACTIVE_ROW_VAR
return