Quantcast

Jump to content

» «
Photo

Marker Trouble

5 replies to this topic
gtasearcher
  • gtasearcher

    No sh*t.

  • Members
  • Joined: 26 Aug 2008

#1

Posted 20 April 2009 - 07:25 AM

My code
CODE
// complete by Demarest
DEFINE OBJECTS 3
DEFINE OBJECT (noname)                
DEFINE OBJECT INDHELIX_BARRIER         // Object number -1
DEFINE OBJECT LOD_LAND014              // Object number -2

DEFINE MISSIONS 2
DEFINE MISSION 0 AT @HOME
DEFINE MISSION 1 AT @SLACK

{$VERSION 1.1.0000}

//-------------MAIN---------------
03A4: name_thread 'MAIN'
01F0: set_max_wanted_level_to 6
0111: set_wasted_busted_check_to 0
00C0: set_current_time 6 0
03F7: load_island_data 0
0053: $PLAYER_CHAR = create_player #NULL at 1428.0859 -193.1254 51.2639
0171: set_player $PLAYER_CHAR z_angle_to 180.0
01F5: $PLAYER_ACTOR = create_emulated_actor_from_player $PLAYER_CHAR
0373: set_camera_directly_behind_player
0363: toggle_model_render_at 1027.25 -933.7499 15.0 radius 50.0 object #INDHELIX_BARRIER 0
03B6: replace_model_at 1027.25 -933.7499 15.0 radius 50.0 from #INDHELIX_BARRIER to #LOD_LAND014
01B6: set_weather 0  
0352: set_actor $PLAYER_ACTOR skin_to 'PLAYER'
0353: refresh_actor $PLAYER_ACTOR
016A: fade 0 0 ms
01B4: set_player $PLAYER_CHAR frozen_state 0
01B7: release_weather
0109: player $PLAYER_CHAR money += $PLAYER_CHAR
0054: store_player $PLAYER_CHAR position_to $var1 $var2 $var3
0180: set_on_mission_flag_to $ONMISSION
01E8: create_forbidden_for_cars_cube 1424.5089 -152.5619 153.5716 1409.4398 -298.59 49.6532
022B: create_forbidden_for_peds_cube 899.4716 -303.2945 108.7239 845.222 -317.7809 7.3684
WAIT 2000
$SLACK_STARTED = 0
start_mission HOME

:MAIN_138
0001: wait 250 ms
0002: jump @MAIN_138

:REPLAY
wait 0
fade 0 3500
wait 3500
start_mission HOME
end_thread

:SAVE
wait 0
02A7: $PORTLAND_SAVE_MARKER = create_icon_marker_and_sphere 17 at 893.5 -306.0625 -100.0
JUMP @1

:1
wait 0
if
$ONMISSION == 0
jf @SAVE
if and
8443:   not player $PLAYER_CHAR in_a_car
00FF:   actor $PLAYER_ACTOR 0 891.0357 -308.1269 8.7239 radius 1.0 1.0 1.0
jf @SAVE
0055: put_player $PLAYER_CHAR at 885.4299 -308.2996 8.5813
wait 0
03D8: show_save_screen
wait 0
jump @SAVE

:SLACK_START
thread "SLACKER_START"
02A7: $VINCENZO_MARKER = create_icon_marker_and_sphere 13 at 1144.0167 -1107.3851 11.8602
03BC: $VIN_SPHERE = create_sphere 1144.0167 -1107.3851 11.8602 2.5
repeat
wait 0
if $ONMISSION == 0
then
  if and
  8443:   not player $PLAYER_CHAR in_a_car
  00FF:   actor $PLAYER_ACTOR 0 1144.0167 -1107.3851 11.8602 radius 2.5 2.5 2.5
  then
   $SLACK_STARTED = 1
   start_mission SLACK  
  end
  END
 if
  03D9:  save_done
 then
 03BD: destroy_sphere $VIN_SPHERE
 03BC: $VIN_SPHERE = create_sphere 1144.0167 -1107.3851 11.8602 2.5
 end
until $SLACK_STARTED == 1
03BD: destroy_sphere $VIN_SPHERE
0164: disable_marker $VINCENZO_MARKER
0164: disable_marker $PORTLAND_SAVE_MARKER
end_thread

:HOME
thread 'HOME1'
gosub @HOME1
if
wasted_or_busted
jf @HOME2
jump @HOME3

:HOME1
01B4: set_player $PLAYER_CHAR frozen_state 0
$ONMISSION = 1
increment_mission_attempts
gosub @MODELS
00A5: 0@ = create_car #KURUMA at 1410.0421 -196.4813 50.2162
0229: set_car 0@ color_to 0 0
0175: set_car 0@ z_angle_to 90.0
00A1: put_actor $PLAYER_ACTOR at 1422.9918 -194.8956 50.1946
009A: 1@ = create_actor 21 #SPECIAL01 at 1417.2784 -199.1626 50.384
015F: set_camera_position 1402.0039 -202.875 50.5144 0.0 0.0 0.0
0160: point_camera 1415.6165 -196.2529 50.3261 2
wait 1000
0173: set_actor 1@ z_angle_to 90.0
0171: set_player $PLAYER_CHAR z_angle_to 90.0
fade 1 1000
02A3: toggle_widescreen 1
0210: player $PLAYER_CHAR look_at_actor 1@
01D4: actor 1@ go_to_car 0@ and_enter_it_as_a_passenger
00BC: text_highpriority 'HOME1' 2000 ms 1
wait 2000
00BC: text_highpriority 'HOME2' 1500 ms 1
wait 1500
00BC: text_highpriority 'HOME3' 1500 ms 1
wait 1500
00BC: text_highpriority 'HOME4' 1500 ms 1
wait 1500
02A3: toggle_widescreen 0
015A: restore_camera
01B4: set_player $PLAYER_CHAR frozen_state 1
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1
wait 0
0171: set_player $PLAYER_CHAR z_angle_to 90.0
repeat
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
JF @HOME3
wait 0
until 00DB:   actor $PLAYER_ACTOR in_car 0@
0164: disable_marker 2@
wait 0
03BC: 4@ = create_sphere 877.2952 -306.444 8.1828 3.5
018A: 3@ = create_checkpoint_at 877.2952 -306.444 8.1828
00BC: text_highpriority 'HOME6' 2000 ms 1
wait 0
repeat
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME3
if
80DB:  not actor $PLAYER_ACTOR in_car 0@
then
03BD: destroy_sphere 4@
0164: disable_marker 3@
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1
wait 0
repeat
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
JF @HOME3
wait 0
until 00DB:   actor $PLAYER_ACTOR in_car 0@
0164: disable_marker 2@
03BC: 4@ = create_sphere 877.2952 -306.444 8.1828 3.5
018A: 3@ = create_checkpoint_at 877.2952 -306.444 8.1828
end
wait 0
until 01B0:   car 0@ stopped 0 877.2952 -306.444 8.1828 radius 3.5 3.5 3.5
01B4: set_player $PLAYER_CHAR frozen_state 0
03BD: destroy_sphere 4@
0164: disable_marker 3@
fade 0 500
wait 500
015F: set_camera_position 888.6827 -300.7185 14.1486 0.0 0.0 0.0
0160: point_camera 878.1043 -305.544 8.7234 2
fade 1 500
02A3: toggle_widescreen 1
00BC: text_highpriority 'HOME7' 3000 ms 1
wait 2500
015F: set_camera_position 880.4828 -309.9949 8.7198 0.0 0.0 0.0
0160: point_camera 888.0446 -310.0063 8.6106 1
wait 2500
03BC: 4@ = create_sphere 1157.8889 -1102.786 11.3002 3.5
018A: 3@ = create_checkpoint_at 1157.8889 -1102.786 11.3002
00BC: text_highpriority 'HOME8' 2000 ms 1
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
015A: restore_camera
wait 0
repeat
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME3
if
80DB:  not actor $PLAYER_ACTOR in_car 0@
then
03BD: destroy_sphere 4@
0164: disable_marker 3@
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1
wait 0
repeat
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
JF @HOME3
wait 0
until 00DB:   actor $PLAYER_ACTOR in_car 0@
0164: disable_marker 2@
03BC: 4@ = create_sphere 1157.8889 -1102.786 11.3002 3.5
018A: 3@ = create_checkpoint_at 1157.8889 -1102.786 11.3002
end
wait 0
until 01B0:   car 0@ stopped 0 1157.8889 -1102.786 11.3002 radius 3.5 3.5 3.5
0164: disable_marker 3@
03BD: destroy_sphere 4@
01B4: set_player $PLAYER_CHAR frozen_state 0
fade 0 1000  
wait 1000
015F: set_camera_position 1160.059 -1081.1836 13.0881 0.0 0.0 0.0
0160: point_camera 1155.4642 -1093.3035 11.8602 2
fade 1 1000
02A3: toggle_widescreen 1
00BC: text_highpriority 'HOME9' 2000 ms 1
wait 2000
00BC: text_highpriority 'HOME10' 2000 ms 1
wait 2000
00BC: text_highpriority 'HOME11' 2000 ms 1
0211: actor 1@ walk_to 1144.0299 -1108.4625
wait 3000
034F: destroy_actor_with_fade 1@ // The actor fades away like a ghost
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
015A: restore_camera
return

:MODELS
wait 0
0247: request_model #KURUMA
038B: load_requested_models
023C: load_special_actor 1 'LUIGI'
wait 0
if and
0248:   model #KURUMA available
023D:   special_actor 1 loaded
jf @MODELS
return

:HOME2
gosub @clean
0318: set_latest_mission_passed 'HOME'
0394: play_music 1
0218: text_1number_styled 'M_PASS' 100 5000 ms 1
0109: player $PLAYER_CHAR money += 100
wait 5000
03E5: text_box 'HOME12'
create_thread @SAVE
wait 4000
03E5: text_box 'HOME13'
create_thread @SLACK_START              
end_thread

:HOME3
gosub @clean
01B4: set_player $PLAYER_CHAR frozen_state 0
create_thread @REPLAY
end_thread

:clean
$ONMISSION = 0
0249: release_model #KURUMA
0296: unload_special_actor 1
mission_cleanup
wait 0
return

:SLACK
thread 'SLACK'
gosub @SLACK1
if
wasted_or_busted
jf @SLACK2
jump @SLACK3

:SLACK1
$ONMISSION = 1
increment_mission_attempts
01B4: set_player $PLAYER_CHAR frozen_state 0
02A3: toggle_widescreen 1
0211: actor $PLAYER_ACTOR walk_to 1144.058 -1108.6025
015F: set_camera_position 1137.4792 -1080.2708 15.1072 0.0 0.0 0.0
0160: point_camera 1142.6434 -1103.0779 11.7102 2
0217: text_styled 'SLACK' 5000 ms 2
wait 1000
fade 0 1500
wait 1500
repeat
wait 0
023C: load_special_actor 1 'LUIGI'
until 023D: special_actor 1 loaded
009A: 0@ = create_actor 21 #SPECIAL01 at 1191.527 -1144.2423 12.04
0173: set_actor 0@ z_angle_to 180.0
015F: set_camera_position 1159.6022 -1156.0386 15.5271 0.0 0.0 0.0
0160: point_camera 1189.7664 -1142.2762 11.8603 2
0055: put_player $PLAYER_CHAR at 1192.871 -1140.1096 11.8603
0173: set_actor $PLAYER_ACTOR z_angle_to 180.0
wait 1000
fade 1 1500
02A3: toggle_widescreen 1
0211: actor $PLAYER_ACTOR walk_to 1194.1383 -1144.3286
wait 2500
011C: actor $PLAYER_ACTOR clear_objective
wait 0  
015F: set_camera_position 1183.111 -1144.5997 13.5963 0.0 0.0 0.0
0160: point_camera 1190.0693 -1144.4313 12.04 1
020F: actor 0@ look_at_player $PLAYER_CHAR
0210: player $PLAYER_CHAR look_at_actor 0@
00BC: text_highpriority 'SLACK1' 2000 ms 1
wait 2000
00BC: text_highpriority 'SLACK2' 2000 ms 1
wait 2000
00BC: text_highpriority 'SLACK3' 2500 ms 1
wait 2500
00BC: text_highpriority 'SLACK4' 2000 ms 1
wait 2000
00BC: text_highpriority 'SLACK5' 1500 ms 1
wait 1500
00BC: text_highpriority 'SLACK6' 1500 ms 1
wait 1500
00BC: text_highpriority 'SLACK7' 3000 ms 1
wait 3000
fade 0 1500
wait 1500
009B: destroy_actor_instantly 0@
0296: unload_special_actor 1
0055: put_player $PLAYER_CHAR at 1180.8098 -1108.0334 11.8602
0173: set_actor $PLAYER_ACTOR z_angle_to 360.0
02EB: restore_camera_with_jumpcut
repeat
wait 0
0247: request_model #WORKER1
038B: load_requested_models
until 0248:   model #WORKER1 available
009A: 1@ = create_actor 21 #WORKER1 at 1320.0994 -235.5278 49.6614
0173: set_actor 1@ z_angle_to 180.0  
wait 1000
fade 1 1500
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
00BC: text_highpriority 'SLACK8' 3000 ms 1
0187: 2@ = create_marker_above_actor 1@        
jump @SLACK4

:SLACK4
wait 0
if
00A2:   actor 1@ alive
jf @SLACK5
if
00FF:   actor $PLAYER_ACTOR 0 1320.1576 -235.5702 49.661 radius 5.0 5.0 5.0
jf @SLACK4
return  

:SLACK2
gosub @s_clean
end_thread

:SLACK3
gosub @s_clean
00BA: text_styled 'M_FAIL' 3000 ms 1
wait 3000
create_thread @SLACK_START
end_thread

:SLACK5
00BC: text_highpriority 'SLACK9' 3000 ms 1
wait 0
jump @SLACK3

:s_clean
$ONMISSION = 0
mission_cleanup
wait 0
return
SB Decompiled Code
CODE
// This file was decompiled using scm.ini published by GtaForums.com on 25.11.05
DEFINE OBJECTS 3
DEFINE OBJECT SANNY BUILDER 3.04      
DEFINE OBJECT INDHELIX_BARRIER         // Object number -1
DEFINE OBJECT LOD_LAND014              // Object number -2

DEFINE MISSIONS 2
DEFINE MISSION 0 AT @HOME1             // Intro Movie
DEFINE MISSION 1 AT @SLACK             // Hospital Info Scene

{$VERSION 1.1.0000}

//-------------MAIN---------------
thread 'MAIN'
01F0: set_max_wanted_level_to 6
set_wb_check_to 0
00C0: set_current_time 6 0
03F7: load_island_data 0
0053: $PLAYER_CHAR = create_player #NULL at 1428.063 -193.125 51.25
0171: set_player $PLAYER_CHAR z_angle_to 180.0
01F5: $PLAYER_ACTOR = create_emulated_actor_from_player $PLAYER_CHAR
0373: set_camera_directly_behind_player
0363: toggle_model_render_at 1027.25 -933.6875 15.0 radius 50.0 object #INDHELIX_BARRIER 0
03B6: replace_model_at 1027.25 -933.6875 15.0 radius 50.0 from #INDHELIX_BARRIER to #LOD_LAND014
set_weather 0
0352: set_actor $PLAYER_ACTOR skin_to 'PLAYER'
0353: refresh_actor $PLAYER_ACTOR
fade 0 0
01B4: set_player $PLAYER_CHAR frozen_state 0
01B7: release_weather
0109: player $PLAYER_CHAR money += $PLAYER_CHAR
0054: store_player $PLAYER_CHAR position_to $VAR1 $VAR2 $VAR3
0180: set_on_mission_flag_to $ONMISSION
01E8: create_forbidden_for_cars_cube 1424.5 -152.5 153.5625 1409.438 -298.5625 49.625
022B: create_forbidden_for_peds_cube 899.4375 -303.25 108.6875 845.1875 -317.75 7.3125
wait 2000
$SLACK_STARTED = 0 // integer values
start_mission HOME1 // Intro Movie

:MAIN_218
wait 250
jump @MAIN_218

:NONAME_1
wait 0
fade 0 3500
wait 3500
start_mission HOME1 // Intro Movie
end_thread

:NONAME_2
wait 0
02A7: $PORTLAND_SAVE_MARKER = create_icon_marker_and_sphere 17 at 893.5 -306.0625 -100.0
jump @NONAME_2_27

:NONAME_2_27
wait 0
if
 $ONMISSION == 0 // integer values
jf @NONAME_2
if and
8443:   not player $PLAYER_CHAR in_a_car
00FF:   actor $PLAYER_ACTOR 0 891.0 -308.125 8.6875 radius 1.0 1.0 1.0
jf @NONAME_2
0055: put_player $PLAYER_CHAR at 885.375 -308.25 8.5625
wait 0
03D8: show_save_screen
wait 0
jump @NONAME_2

:SLACKER_START
thread "SLACKER_START"
02A7: $VINCENZO_MARKER = create_icon_marker_and_sphere 13 at 1144.0 -1107.375 11.8125
03BC: $VIN_SPHERE = create_sphere 1144.0 -1107.375 11.8125 2.5

:SLACKER_START_50
wait 0
if
 $ONMISSION == 0 // integer values
jf @SLACKER_START_124
if and
8443:   not player $PLAYER_CHAR in_a_car
00FF:   actor $PLAYER_ACTOR 0 1144.0 -1107.375 11.8125 radius 2.5 2.5 2.5
jf @SLACKER_START_124
$SLACK_STARTED = 1 // integer values
start_mission SLACK // Hospital Info Scene

:SLACKER_START_124
if
03D9:   save_done
jf @SLACKER_START_159
03BD: destroy_sphere $VIN_SPHERE
03BC: $VIN_SPHERE = create_sphere 1144.0 -1107.375 11.8125 2.5

:SLACKER_START_159
 $SLACK_STARTED == 1 // integer values
jf @SLACKER_START_50
03BD: destroy_sphere $VIN_SPHERE
0164: disable_marker $VINCENZO_MARKER
0164: disable_marker $PORTLAND_SAVE_MARKER
end_thread

//-------------Mission 0---------------
// Originally: Intro Movie

:HOME1
thread 'HOME1'
gosub @HOME1_37
if
wasted_or_busted
jf @HOME1_1236
jump @HOME1_1329

:HOME1_37
01B4: set_player $PLAYER_CHAR frozen_state 0
$ONMISSION = 1 // integer values
increment_mission_attempts
gosub @HOME1_1189
00A5: 0@ = create_car #KURUMA at 1410.0 -196.4375 50.1875
0229: set_car 0@ color_to 0 0
0175: set_car 0@ z_angle_to 90.0
00A1: put_actor $PLAYER_ACTOR at 1422.938 -194.875 50.1875
009A: 1@ = create_actor 21 #SPECIAL01 at 1417.25 -199.125 50.375
015F: set_camera_position 1402.0 -202.875 50.5 0.0 0.0 0.0
0160: point_camera 1415.563 -196.25 50.3125 2
wait 1000
0173: set_actor 1@ z_angle_to 90.0
0171: set_player $PLAYER_CHAR z_angle_to 90.0
fade 1 1000
02A3: toggle_widescreen 1
0210: player $PLAYER_CHAR look_at_actor 1@
01D4: actor 1@ go_to_car 0@ and_enter_it_as_a_passenger
00BC: text_highpriority 'HOME1' 2000 ms 1  // I've got you a nice little place to stay, ~n~Toni.
wait 2000
00BC: text_highpriority 'HOME2' 1500 ms 1  // It's got you written all over it.
wait 1500
00BC: text_highpriority 'HOME3' 1500 ms 1  // We'll head there first.
wait 1500
00BC: text_highpriority 'HOME4' 1500 ms 1  // You're all heart.
wait 1500
02A3: toggle_widescreen 0
015A: restore_camera
01B4: set_player $PLAYER_CHAR frozen_state 1
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1  // Get in the ~b~car.
wait 0
0171: set_player $PLAYER_CHAR z_angle_to 90.0

:HOME1_334
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME1_1329
wait 0
00DB:   actor $PLAYER_ACTOR in_car 0@
jf @HOME1_334
0164: disable_marker 2@
wait 0
03BC: 4@ = create_sphere 877.25 -306.4375 8.125 3.5
018A: 3@ = create_checkpoint_at 877.25 -306.4375 8.125
00BC: text_highpriority 'HOME6' 2000 ms 1  // Drive Vincenzo to your ~p~hideout.
wait 0

:HOME1_437
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME1_1329
if
80DB:   not actor $PLAYER_ACTOR in_car 0@
jf @HOME1_598
03BD: destroy_sphere 4@
0164: disable_marker 3@
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1  // Get in the ~b~car.
wait 0

:HOME1_518
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME1_1329
wait 0
00DB:   actor $PLAYER_ACTOR in_car 0@
jf @HOME1_518
0164: disable_marker 2@
03BC: 4@ = create_sphere 877.25 -306.4375 8.125 3.5
018A: 3@ = create_checkpoint_at 877.25 -306.4375 8.125

:HOME1_598
wait 0
01B0:   car 0@ stopped 0 877.25 -306.4375 8.125 radius 3.5 3.5 3.5
jf @HOME1_437
01B4: set_player $PLAYER_CHAR frozen_state 0
03BD: destroy_sphere 4@
0164: disable_marker 3@
fade 0 500
wait 500
015F: set_camera_position 888.625 -300.6875 14.125 0.0 0.0 0.0
0160: point_camera 878.0625 -305.5 8.6875 2
fade 1 500
02A3: toggle_widescreen 1
00BC: text_highpriority 'HOME7' 3000 ms 1  // This sh*thole is supposed to be my home?...
wait 2500
015F: set_camera_position 880.4375 -309.9375 8.6875 0.0 0.0 0.0
0160: point_camera 888.0 -310.0 8.5625 1
wait 2500
03BC: 4@ = create_sphere 1157.875 -1102.75 11.25 3.5
018A: 3@ = create_checkpoint_at 1157.875 -1102.75 11.25
00BC: text_highpriority 'HOME8' 2000 ms 1  // Drive Vincenzo to his ~p~place ~w~in Atlatinque Queys.
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
015A: restore_camera
wait 0

:HOME1_828
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME1_1329
if
80DB:   not actor $PLAYER_ACTOR in_car 0@
jf @HOME1_989
03BD: destroy_sphere 4@
0164: disable_marker 3@
0186: 2@ = create_marker_above_car 0@
00BC: text_highpriority 'HOME5' 2000 ms 1  // Get in the ~b~car.
wait 0

:HOME1_909
wait 0
if and
00A2:   actor 1@ alive
8119:   not car 0@ wrecked
jf @HOME1_1329
wait 0
00DB:   actor $PLAYER_ACTOR in_car 0@
jf @HOME1_909
0164: disable_marker 2@
03BC: 4@ = create_sphere 1157.875 -1102.75 11.25 3.5
018A: 3@ = create_checkpoint_at 1157.875 -1102.75 11.25

:HOME1_989
wait 0
01B0:   car 0@ stopped 0 1157.875 -1102.75 11.25 radius 3.5 3.5 3.5
jf @HOME1_828
0164: disable_marker 3@
03BD: destroy_sphere 4@
01B4: set_player $PLAYER_CHAR frozen_state 0
fade 0 1000
wait 1000
015F: set_camera_position 1160.0 -1081.125 13.0625 0.0 0.0 0.0
0160: point_camera 1155.438 -1093.25 11.8125 2
fade 1 1000
02A3: toggle_widescreen 1
00BC: text_highpriority 'HOME9' 2000 ms 1  // Hey, apartments cost money, Tony.
wait 2000
00BC: text_highpriority 'HOME10' 2000 ms 1  // Just you remember who pays the bills around here.
wait 2000
00BC: text_highpriority 'HOME11' 2000 ms 1  // ME. Daddy Vincenzo over here. ~n~So I better see you here real soon!
0211: actor 1@ walk_to 1144.0 -1108.438
wait 3000
034F: destroy_actor_with_fade 1@ // The actor fades away like a ghost
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
015A: restore_camera
return

:HOME1_1189
wait 0
0247: request_model #KURUMA
038B: load_requested_models
023C: load_special_actor 1 'LUIGI'
wait 0
if and
0248:   model #KURUMA available
023D:   special_actor 1 loaded
jf @HOME1_1189
return

:HOME1_1236
gosub @HOME1_1353
0318: set_latest_mission_passed 'HOME'  // Home Sweet Home
0394: play_music 1
0218: text_1number_styled 'M_PASS' 100 5000 ms 1  // MISSION PASSED! $~1~
0109: player $PLAYER_CHAR money += 100
wait 5000
03E5: text_box 'HOME12'  // You can visit your ~h~safehouse ~w~to save your game, and change your clothes.
create_thread @NONAME_2
wait 4000
03E5: text_box 'HOME13'  // Go to the ~b~V~w~ on the radar to start the next mission.
create_thread @SLACKER_START
end_thread

:HOME1_1329
gosub @HOME1_1353
01B4: set_player $PLAYER_CHAR frozen_state 0
create_thread @NONAME_1
end_thread

:HOME1_1353
$ONMISSION = 0 // integer values
0249: release_model #KURUMA
0296: unload_special_actor 1
mission_cleanup
wait 0
return

//-------------Mission 1---------------
// Originally: Hospital Info Scene

:SLACK
thread 'SLACK'
gosub @SLACK_37
if
wasted_or_busted
jf @SLACK_674
jump @SLACK_683

:SLACK_37
$ONMISSION = 1 // integer values
increment_mission_attempts
01B4: set_player $PLAYER_CHAR frozen_state 0
02A3: toggle_widescreen 1
0211: actor $PLAYER_ACTOR walk_to 1144.0 -1108.563
015F: set_camera_position 1137.438 -1080.25 15.0625 0.0 0.0 0.0
0160: point_camera 1142.625 -1103.063 11.6875 2
0217: text_styled 'SLACK' 5000 ms 2  // Slacker
wait 1000
fade 0 1500
wait 1500

:SLACK_133
wait 0
023C: load_special_actor 1 'LUIGI'
023D:   special_actor 1 loaded
jf @SLACK_133
009A: 0@ = create_actor 21 #SPECIAL01 at 1191.5 -1144.188 12.0
0173: set_actor 0@ z_angle_to 180.0
015F: set_camera_position 1159.563 -1156.0 15.5 0.0 0.0 0.0
0160: point_camera 1189.75 -1142.25 11.8125 2
0055: put_player $PLAYER_CHAR at 1192.813 -1140.063 11.8125
0173: set_actor $PLAYER_ACTOR z_angle_to 180.0
wait 1000
fade 1 1500
02A3: toggle_widescreen 1
0211: actor $PLAYER_ACTOR walk_to 1194.125 -1144.313
wait 2500
011C: actor $PLAYER_ACTOR clear_objective
wait 0
015F: set_camera_position 1183.063 -1144.563 13.5625 0.0 0.0 0.0
0160: point_camera 1190.063 -1144.375 12.0 1
020F: actor 0@ look_at_player $PLAYER_CHAR
0210: player $PLAYER_CHAR look_at_actor 0@
00BC: text_highpriority 'SLACK1' 2000 ms 1  // We got a dealer, working on north Chinatown patch.
wait 2000
00BC: text_highpriority 'SLACK2' 2000 ms 1  // The lazy bastard hasn't brought any cash in, in days.
wait 2000
00BC: text_highpriority 'SLACK3' 2500 ms 1  // Maybe he needs to get some encouragement and get off his ass and do some work.
wait 2500
00BC: text_highpriority 'SLACK4' 2000 ms 1  // Acting like a bitch - he kinda reminds me of you.
wait 2000
00BC: text_highpriority 'SLACK5' 1500 ms 1  // What are you trying to say?
wait 1500
00BC: text_highpriority 'SLACK6' 1500 ms 1  // I ain't trying to say nothing!
wait 1500
00BC: text_highpriority 'SLACK7' 3000 ms 1  // I'm telling you to get your ass over there and make sure this asshole starts brining some God damn money!
wait 3000
fade 0 1500
wait 1500
009B: destroy_actor_instantly 0@
0296: unload_special_actor 1
0055: put_player $PLAYER_CHAR at 1180.75 -1108.0 11.8125
0173: set_actor $PLAYER_ACTOR z_angle_to 360.0
02EB: restore_camera_with_jumpcut

:SLACK_516
wait 0
0247: request_model #WORKER1
038B: load_requested_models
0248:   model #WORKER1 available
jf @SLACK_516
009A: 1@ = create_actor 21 #WORKER1 at 1320.063 -235.5 49.625
0173: set_actor 1@ z_angle_to 180.0
wait 1000
fade 1 1500
02A3: toggle_widescreen 0
01B4: set_player $PLAYER_CHAR frozen_state 1
00BC: text_highpriority 'SLACK8' 3000 ms 1  // Pick up Vincenzo's ~g~dealer~w~ from Saint Mark's district.
0187: 2@ = create_marker_above_actor 1@
jump @SLACK_616

:SLACK_616
wait 0
if
00A2:   actor 1@ alive
jf @SLACK_720
if
00FF:   actor $PLAYER_ACTOR 0 1320.125 -235.5625 49.625 radius 5.0 5.0 5.0
jf @SLACK_616
return

:SLACK_674
gosub @SLACK_746
end_thread

:SLACK_683
gosub @SLACK_746
00BA: text_styled 'M_FAIL' 3000 ms 1  // MISSION FAILED!
wait 3000
create_thread @SLACKER_START
end_thread

:SLACK_720
00BC: text_highpriority 'SLACK9' 3000 ms 1  // ~r~The dealer is dead!
wait 0
jump @SLACK_683

:SLACK_746
$ONMISSION = 0 // integer values
mission_cleanup
wait 0
return
Thingy is, why doesn't $VINCENZO_MARKER appear on the radar? The save one does, but his one doesn't sad.gif

I hope you understand my code, I tried to make it as clean as possible - with no variables you wouldn't understand I hope smile.gif

ms.cooldude
  • ms.cooldude

    The power is in your hands

  • Members
  • Joined: 24 Oct 2005

#2

Posted 20 April 2009 - 09:52 PM

So the sphere appears and the mission starts?
btw this is GTA3 right?

Andrew
  • Andrew

  • Inactive Staff
  • Joined: 21 Jul 2003
  • None

#3

Posted 20 April 2009 - 10:12 PM

Funny you mention your code, but clearly at the top of the script it states:

CODE

//complete by Demarest


How much of that code is yours?

rebel_36
  • rebel_36

    dot connectah

  • Members
  • Joined: 14 Mar 2004

#4

Posted 20 April 2009 - 11:16 PM

dems stripped scm comes with sanny and it always says "made by dem" or whatever at the top so it could very well be his own code

Dutchy3010
  • Dutchy3010

    Female SCM coder!

  • Moderator
  • Joined: 30 Jul 2006
  • Netherlands

#5

Posted 21 April 2009 - 12:01 AM Edited by Dutchy3010, 21 April 2009 - 12:05 AM.

After checking the code for a long time, I could have found a possible fault for it:

CODE
:SAVE
wait 0
02A7: $PORTLAND_SAVE_MARKER = create_icon_marker_and_sphere 17 at 893.5 -306.0625 -100.0
JUMP @1

:1
wait 0
if
$ONMISSION == 0
jf @SAVE
if and
8443:   not player $PLAYER_CHAR in_a_car
00FF:   actor $PLAYER_ACTOR 0 891.0357 -308.1269 8.7239 radius 1.0 1.0 1.0
jf @SAVE
0055: put_player $PLAYER_CHAR at 885.4299 -308.2996 8.5813
wait 0
03D8: show_save_screen
wait 0
jump @SAVE

When the player isn't on the right place, or is in a car, the code jumps to SAVE. So there will be many icons on top of each other at the same location.

CODE
:HOME2
gosub @clean
0318: set_latest_mission_passed 'HOME'
0394: play_music 1
0218: text_1number_styled 'M_PASS' 100 5000 ms 1
0109: player $PLAYER_CHAR money += 100
wait 5000
03E5: text_box 'HOME12'
create_thread @SAVE
wait 4000
03E5: text_box 'HOME13'
create_thread @SLACK_START              
end_thread

In this part, you will see that the SAVE thread will be started sooner then the SLACK_START thread. So in the 4 seconds between those, there can be very much icons on the map because of the loop above. It is likely that a there is a limit on the number of icons, so the "$VINCENZO_MARKER"-icon won't appear any more.

There is a very simple solution:
CODE
:1
wait 0
if
$ONMISSION == 0
jf @1
if and
8443:   not player $PLAYER_CHAR in_a_car
00FF:   actor $PLAYER_ACTOR 0 891.0357 -308.1269 8.7239 radius 1.0 1.0 1.0
jf @1
0055: put_player $PLAYER_CHAR at 885.4299 -308.2996 8.5813
wait 0
03D8: show_save_screen
wait 0
jump @1


QUOTE
dems stripped scm comes with sanny and it always says "made by dem" or whatever at the top so it could very well be his own code

Oh, I didn't know. Sorry about that. wink.gif

gtasearcher
  • gtasearcher

    No sh*t.

  • Members
  • Joined: 26 Aug 2008

#6

Posted 21 April 2009 - 05:48 AM

Thanks guys, but the "V" still doesn't appear sad.gif

Tough your solution, Dutchy, fixed another bug of another marker wich didn't appear in the next mission, thanks smile.gif




1 user(s) are reading this topic

0 members, 1 guests, 0 anonymous users